bertos/cpu/arm/scripts/arm7tdmi_ram.ld

   1 /**
   2  * \file
   3  * <!--
   4  * This file is part of BeRTOS.
   5  *
   6  * Bertos is free software; you can redistribute it and/or modify
   7  * it under the terms of the GNU General Public License as published by
   8  * the Free Software Foundation; either version 2 of the License, or
   9  * (at your option) any later version.
  10  *
  11  * This program is distributed in the hope that it will be useful,
  12  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  13  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14  * GNU General Public License for more details.
  15  *
  16  * You should have received a copy of the GNU General Public License
  17  * along with this program; if not, write to the Free Software
  18  * Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA  02110-1301  USA
  19  *
  20  * As a special exception, you may use this file as part of a free software
  21  * library without restriction.  Specifically, if other files instantiate
  22  * templates or use macros or inline functions from this file, or you compile
  23  * this file and link it with other files to produce an executable, this
  24  * file does not by itself cause the resulting executable to be covered by
  25  * the GNU General Public License.  This exception does not however
  26  * invalidate any other reasons why the executable file might be covered by
  27  * the GNU General Public License.
  28  *
  29  * Copyright 2010 Develer S.r.l. (http://www.develer.com/)
  30  *
  31  * -->
  32  *
  33  * \author Daniele Basile <asterix@develer.com>
  34  *
  35  * \brief Linker Script for Atmel AT91SAM7 family processors, RAM execution.
  36  *
  37  */
  38
  39 ENTRY(_init)
  40 OUTPUT_FORMAT("elf32-littlearm", "elf32-bigarm", "elf32-littlearm")
  41 OUTPUT_ARCH(arm)
  42
  43 /*
  44  * Define stack size here
  45  */
  46 FIQ_STACK_SIZE = 0x0100;
  47 IRQ_STACK_SIZE = 0x0400;
  48 ABT_STACK_SIZE = 0x0100;
  49 UND_STACK_SIZE = 0x0100;
  50 SVC_STACK_SIZE = 0x1000;
  51
  52 /*
  53  * Allocate section memory
  54  */
  55 SECTIONS
  56 {
  57         .text :
  58         {
  59                 KEEP(*(.vectors));
  60                 . = ALIGN (4);
  61                 KEEP(*(.init));
  62                 . = ALIGN (4);
  63                 *(.rodata .rodata.*);
  64                 . = ALIGN (4);
  65                 *(.text .text.*);
  66                 . = ALIGN (4);
  67                 *(.glue_7t);
  68                 . = ALIGN(4);
  69                 *(.glue_7);
  70                 . = ALIGN(4);
  71                 *(.gcc*);
  72                 . = ALIGN(4);
  73                 *(.ctors);
  74                 . = ALIGN(4);
  75                 *(.dtors);
  76         } > ram
  77
  78         _etext = .;
  79         PROVIDE (__etext = .);
  80
  81         .data : AT (_etext)
  82         {
  83                 PROVIDE (__data_start = .);
  84                 *(.data .data.*)
  85                 . = ALIGN (4);
  86                 _edata = .;
  87                 PROVIDE (__data_end = .);
  88         } > ram
  89
  90         .bss :
  91         {
  92                 PROVIDE (__bss_start = .);
  93                 *(.bss .bss.*)
  94                 . = ALIGN(4);
  95                 *(COMMON)
  96                 . = ALIGN(4);
  97                 PROVIDE (__bss_end = .);
  98         } > ram
  99
 100         /*
 101          * Allocate stack at the end of bss section.
 102          * Data heap is allocated at end of stack.
 103          */
 104         PROVIDE (__stack_start = .);
 105
 106         PROVIDE (__stack_fiq_start = .);
 107         . += FIQ_STACK_SIZE;
 108         . = ALIGN(8);
 109         PROVIDE (__stack_fiq_end = .);
 110
 111         PROVIDE (__stack_irq_start = .);
 112         . += IRQ_STACK_SIZE;
 113         . = ALIGN(8);
 114         PROVIDE (__stack_irq_end = .);
 115
 116         PROVIDE (__stack_abt_start = .);
 117         . += ABT_STACK_SIZE;
 118         . = ALIGN(8);
 119         PROVIDE (__stack_abt_end = .);
 120
 121         PROVIDE (__stack_und_start = .);
 122         . += UND_STACK_SIZE;
 123         . = ALIGN(8);
 124         PROVIDE (__stack_und_end = .);
 125
 126         PROVIDE (__stack_svc_start = .);
 127         . += SVC_STACK_SIZE;
 128         . = ALIGN(8);
 129         PROVIDE (__stack_svc_end = .);
 130
 131         PROVIDE (__stack_end = .);
 132
 133         PROVIDE (__heap_start = .);
 134 }