bertos/cpu/arm/scripts/arm7tdmi_rom.ld

   1 /**
   2  * \file
   3  * <!--
   4  * This file is part of BeRTOS.
   5  *
   6  * Bertos is free software; you can redistribute it and/or modify
   7  * it under the terms of the GNU General Public License as published by
   8  * the Free Software Foundation; either version 2 of the License, or
   9  * (at your option) any later version.
  10  *
  11  * This program is distributed in the hope that it will be useful,
  12  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  13  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14  * GNU General Public License for more details.
  15  *
  16  * You should have received a copy of the GNU General Public License
  17  * along with this program; if not, write to the Free Software
  18  * Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA  02110-1301  USA
  19  *
  20  * As a special exception, you may use this file as part of a free software
  21  * library without restriction.  Specifically, if other files instantiate
  22  * templates or use macros or inline functions from this file, or you compile
  23  * this file and link it with other files to produce an executable, this
  24  * file does not by itself cause the resulting executable to be covered by
  25  * the GNU General Public License.  This exception does not however
  26  * invalidate any other reasons why the executable file might be covered by
  27  * the GNU General Public License.
  28  *
  29  * Copyright 2010 Develer S.r.l. (http://www.develer.com/)
  30  *
  31  * -->
  32  *
  33  * \author Daniele Basile <asterix@develer.com>
  34  *
  35  * \brief Linker Script for Atmel AT91SAM7 family processors, ROM execution.
  36  *
  37  */
  38
  39 OUTPUT_FORMAT("elf32-littlearm", "elf32-bigarm", "elf32-littlearm")
  40 OUTPUT_ARCH(arm)
  41
  42 /*
  43  * Define stack size here
  44  */
  45 FIQ_STACK_SIZE = 0x0100;
  46 IRQ_STACK_SIZE = 0x0400;
  47 ABT_STACK_SIZE = 0x0100;
  48 UND_STACK_SIZE = 0x0100;
  49 SVC_STACK_SIZE = 0x1000;
  50
  51 /*
  52  * Allocate section memory
  53  */
  54 SECTIONS
  55 {
  56         .text :
  57         {
  58                 KEEP(*(.vectors));
  59                 . = ALIGN (4);
  60                 *(.init);
  61                 . = ALIGN (4);
  62                 *(.rodata .rodata.*);
  63                 . = ALIGN (4);
  64                 *(.text .text.*);
  65                 . = ALIGN (4);
  66                 *(.glue_7t);
  67                 . = ALIGN(4);
  68                 *(.glue_7);
  69                 . = ALIGN(4);
  70                 *(.gcc*);
  71                 . = ALIGN(4);
  72                 *(.ctors);
  73                 . = ALIGN(4);
  74                 *(.dtors);
  75                 _etext = .;
  76                 PROVIDE (__etext = .);
  77         } > rom
  78
  79
  80         .data : AT (_etext)
  81         {
  82                 PROVIDE (__data_start = .);
  83                 *(.data .data.*)
  84                 . = ALIGN (4);
  85                 _edata = .;
  86                 PROVIDE (__data_end = .);
  87         } > ram
  88
  89         .bss :
  90         {
  91                 PROVIDE (__bss_start = .);
  92                 *(.bss .bss.*)
  93                 . = ALIGN(4);
  94                 *(COMMON)
  95                 . = ALIGN(4);
  96                 PROVIDE (__bss_end = .);
  97         } > ram
  98
  99         /*
 100          * Allocate stack at the end of bss section.
 101          * Data heap is allocated at end of stack.
 102          */
 103         PROVIDE (__stack_start = .);
 104
 105         PROVIDE (__stack_fiq_start = .);
 106         . += FIQ_STACK_SIZE;
 107         . = ALIGN(8);
 108         PROVIDE (__stack_fiq_end = .);
 109
 110         PROVIDE (__stack_irq_start = .);
 111         . += IRQ_STACK_SIZE;
 112         . = ALIGN(8);
 113         PROVIDE (__stack_irq_end = .);
 114
 115         PROVIDE (__stack_abt_start = .);
 116         . += ABT_STACK_SIZE;
 117         . = ALIGN(8);
 118         PROVIDE (__stack_abt_end = .);
 119
 120         PROVIDE (__stack_und_start = .);
 121         . += UND_STACK_SIZE;
 122         . = ALIGN(8);
 123         PROVIDE (__stack_und_end = .);
 124
 125         PROVIDE (__stack_svc_start = .);
 126         . += SVC_STACK_SIZE;
 127         . = ALIGN(8);
 128         PROVIDE (__stack_svc_end = .);
 129
 130         PROVIDE (__stack_end = .);
 131
 132         PROVIDE (__heap_start = .);
 133 }