bertos/cpu/arm/scripts/at91sam7_128_rom.ld

   1 /**
   2  * \file
   3  * <!--
   4  * This file is part of BeRTOS.
   5  *
   6  * Bertos is free software; you can redistribute it and/or modify
   7  * it under the terms of the GNU General Public License as published by
   8  * the Free Software Foundation; either version 2 of the License, or
   9  * (at your option) any later version.
  10  *
  11  * This program is distributed in the hope that it will be useful,
  12  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  13  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14  * GNU General Public License for more details.
  15  *
  16  * You should have received a copy of the GNU General Public License
  17  * along with this program; if not, write to the Free Software
  18  * Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA  02110-1301  USA
  19  *
  20  * As a special exception, you may use this file as part of a free software
  21  * library without restriction.  Specifically, if other files instantiate
  22  * templates or use macros or inline functions from this file, or you compile
  23  * this file and link it with other files to produce an executable, this
  24  * file does not by itself cause the resulting executable to be covered by
  25  * the GNU General Public License.  This exception does not however
  26  * invalidate any other reasons why the executable file might be covered by
  27  * the GNU General Public License.
  28  *
  29  * Copyright 2007 Develer S.r.l. (http://www.develer.com/)
  30  *
  31  * -->
  32  *
  33  * \version $Id: sysirq_at91.c 18273 2007-10-11 14:53:02Z batt $
  34  *
  35  * \author Daniele Basile <asterix@develer.com>
  36  *
  37  * \brief Script linker for Atmel AT91SAM7_128 family processors.
  38  *
  39  */
  40
  41
  42 ENTRY(_init)
  43 SEARCH_DIR(.)
  44 OUTPUT_FORMAT("elf32-littlearm", "elf32-bigarm", "elf32-littlearm")
  45 OUTPUT_ARCH(arm)
  46
  47 /*
  48  * Define memory configuration for AT91SAM7_128 family
  49  */
  50 MEMORY
  51 {
  52   rom(rx) : org = 0x00100000, len = 128k
  53   ram(rwx) : org = 0x00200000, len = 64k
  54 }
  55
  56
  57 /*
  58  * Define stack size here
  59  */
  60 FIQ_STACK_SIZE = 0x0100;
  61 IRQ_STACK_SIZE = 0x0400;
  62 ABT_STACK_SIZE = 0x0100;
  63 UND_STACK_SIZE = 0x0100;
  64 SVC_STACK_SIZE = 0x1000;
  65
  66 /*
  67  * Allocate section memory
  68  */
  69 SECTIONS
  70 {
  71         .text :
  72         {
  73                 KEEP(*(.vectors));
  74                 . = ALIGN (4);
  75                 KEEP(*(.init));
  76                 . = ALIGN (4);
  77                 *(.rodata .rodata.*);
  78                 . = ALIGN (4);
  79                 *(.text .text.*);
  80                 . = ALIGN (4);
  81                 *(.glue_7t);
  82                 . = ALIGN(4);
  83                 *(.glue_7);
  84                 . = ALIGN(4);
  85         } > rom
  86
  87         _etext = .;
  88         PROVIDE (__etext = .);
  89
  90         .data : AT (_etext)
  91         {
  92                 PROVIDE (__data_start = .);
  93                 *(.data .data.*)
  94                 . = ALIGN (4);
  95                 _edata = .;
  96                 PROVIDE (__data_end = .);
  97         } > ram
  98
  99         .bss :
 100         {
 101                 PROVIDE (__bss_start = .);
 102                 *(.bss .bss.*)
 103                 . = ALIGN(4);
 104                 *(COMMON)
 105                 . = ALIGN(4);
 106                 PROVIDE (__bss_end = .);
 107         } > ram
 108
 109         /*
 110          * Allocated stack at the end of bss section.
 111          * Data heap is allocate at end of stack.
 112          */
 113         PROVIDE (__stack_start = .);
 114
 115         PROVIDE (__stack_fiq_start = .);
 116         . += FIQ_STACK_SIZE;
 117         . = ALIGN(8);
 118         PROVIDE (__stack_fiq_end = .);
 119
 120         PROVIDE (__stack_irq_start = .);
 121         . += IRQ_STACK_SIZE;
 122         . = ALIGN(8);
 123         PROVIDE (__stack_irq_end = .);
 124
 125         PROVIDE (__stack_abt_start = .);
 126         . += ABT_STACK_SIZE;
 127         . = ALIGN(8);
 128         PROVIDE (__stack_abt_end = .);
 129
 130         PROVIDE (__stack_und_start = .);
 131         . += UND_STACK_SIZE;
 132         . = ALIGN(8);
 133         PROVIDE (__stack_und_end = .);
 134
 135         PROVIDE (__stack_svc_start = .);
 136         . += SVC_STACK_SIZE;
 137         . = ALIGN(8);
 138         PROVIDE (__stack_svc_end = .);
 139
 140         PROVIDE (__stack_end = .);
 141
 142         PROVIDE (__heap_start = .);
 143 }