kern/switch_dsp56k.c

   1 /*!
   2  * \file
   3  * <!--
   4  * Copyright 2004 Develer S.r.l. (http://www.develer.com/)
   5  * This file is part of DevLib - See devlib/README for information.
   6  * -->
   7  *
   8  * \version $Id$
   9  *
  10  * \author Giovanni Bajo <rasky@develer.com>
  11  *
  12  * \brief DSP5680x task switching support
  13  */
  14
  15 /*
  16  * $Log$
  17  * Revision 1.3  2004/07/30 14:24:16  rasky
  18  * Task switching con salvataggio perfetto stato di interrupt (SR)
  19  * Kernel monitor per dump informazioni su stack dei processi
  20  *
  21  * Revision 1.2  2004/06/03 11:27:09  bernie
  22  * Add dual-license information.
  23  *
  24  * Revision 1.1  2004/05/23 17:27:00  bernie
  25  * Import kern/ subdirectory.
  26  *
  27  */
  28
  29 void asm_switch_context(void ** new_sp/*R2*/, void ** save_sp/*R3*/);
  30 asm void asm_switch_context(void ** new_sp, void ** save_sp)
  31 {
  32         lea   (SP)+
  33
  34         ; From the manual:
  35         ; The compiler uses page 0 address locations X: 0x0030 - 0x003F as register
  36         ; variables. Frequently accessed local variables are assigned to the page 0
  37         ; registers instead of to stack locations so that load and store instructions
  38         ; are shortened. Addresses X: 0x0030 - 0x0037 (page 0 registers MR0-MR7) are
  39         ; volatile registers and can be overwritten. The remaining registers (page 0
  40         ; registers MR8-MR15) are treated as non-volatile and, if used by a routine,
  41         ; must be saved on entry and restored on exit.
  42         ;
  43         ; So, register 0x30-0x37 are caller-save, while 0x38-0x3F are callee-save.
  44         move  x:<$38,y1
  45         move  y1,x:(SP)+
  46         move  x:<$39,y1
  47         move  y1,x:(SP)+
  48         move  x:<$3A,y1
  49         move  y1,x:(SP)+
  50         move  x:<$3B,y1
  51         move  y1,x:(SP)+
  52         move  x:<$3C,y1
  53         move  y1,x:(SP)+
  54         move  x:<$3D,y1
  55         move  y1,x:(SP)+
  56         move  x:<$3E,y1
  57         move  y1,x:(SP)+
  58         move  x:<$3F,y1
  59         move  y1,x:(SP)
  60
  61         ;
  62         ; Switch stacks
  63         nop
  64         move SP, x:(R3)
  65         nop
  66         move x:(R2), SP
  67         nop
  68
  69         ;
  70         ; restore all saved registers
  71         ;
  72         pop   y1
  73         move  y1,x:<$3F
  74         pop   y1
  75         move  y1,x:<$3E
  76         pop   y1
  77         move  y1,x:<$3D
  78         pop   y1
  79         move  y1,x:<$3C
  80         pop   y1
  81         move  y1,x:<$3B
  82         pop   y1
  83         move  y1,x:<$3A
  84         pop   y1
  85         move  y1,x:<$39
  86         pop   y1
  87         move  y1,x:<$38
  88
  89         ; SR is already pushed on the stack (normal call context). Use RTI to restore
  90         ; it, so that interrupt status is preserved across the tasks.
  91         rti
  92 }
  93
  94 int asm_switch_version(void);
  95 int asm_switch_version(void)
  96 {
  97         return 1;
  98 }