src/keytrans/pem2openpgp

   1 #!/usr/bin/perl -w -T
   2
   3 # pem2openpgp: take a PEM-encoded RSA private-key on standard input, a
   4 # User ID as the first argument, and generate an OpenPGP secret key
   5 # and certificate from it.
   6
   7 # WARNING: the secret key material *will* appear on stdout (albeit in
   8 # OpenPGP form) -- if you redirect stdout to a file, make sure the
   9 # permissions on that file are appropriately locked down!
  10
  11 # Usage:
  12
  13 # pem2openpgp 'ssh://'$(hostname -f) < /etc/ssh/ssh_host_rsa_key | gpg --import
  14
  15 # Authors:
  16 #  Jameson Rollins <jrollins@finestructure.net>
  17 #  Daniel Kahn Gillmor <dkg@fifthhorseman.net>
  18
  19 # Started on: 2009-01-07 02:01:19-0500
  20
  21 # License: GPL v3 or later (we may need to adjust this given that this
  22 # connects to OpenSSL via perl)
  23
  24 use strict;
  25 use warnings;
  26 use File::Basename;
  27 use Crypt::OpenSSL::RSA;
  28 use Crypt::OpenSSL::Bignum;
  29 use Crypt::OpenSSL::Bignum::CTX;
  30 use Digest::SHA1;
  31 use MIME::Base64;
  32
  33 ## make sure all length() and substr() calls use bytes only:
  34 use bytes;
  35
  36 my $old_format_packet_lengths = { one => 0,
  37                                   two => 1,
  38                                   four => 2,
  39                                   indeterminate => 3,
  40 };
  41
  42 # see RFC 4880 section 9.1 (ignoring deprecated algorithms for now)
  43 my $asym_algos = { rsa => 1,
  44                    elgamal => 16,
  45                    dsa => 17,
  46                    };
  47
  48 # see RFC 4880 section 9.2
  49 my $ciphers = { plaintext => 0,
  50                 idea => 1,
  51                 tripledes => 2,
  52                 cast5 => 3,
  53                 blowfish => 4,
  54                 aes128 => 7,
  55                 aes192 => 8,
  56                 aes256 => 9,
  57                 twofish => 10,
  58               };
  59
  60 # see RFC 4880 section 9.3
  61 my $zips = { uncompressed => 0,
  62              zip => 1,
  63              zlib => 2,
  64              bzip2 => 3,
  65            };
  66
  67 # see RFC 4880 section 9.4
  68 my $digests = { md5 => 1,
  69                 sha1 => 2,
  70                 ripemd160 => 3,
  71                 sha256 => 8,
  72                 sha384 => 9,
  73                 sha512 => 10,
  74                 sha224 => 11,
  75               };
  76
  77 # see RFC 4880 section 5.2.3.21
  78 my $usage_flags = { certify => 0x01,
  79                     sign => 0x02,
  80                     encrypt_comms => 0x04,
  81                     encrypt_storage => 0x08,
  82                     encrypt => 0x0c, ## both comms and storage
  83                     split => 0x10, # the private key is split via secret sharing
  84                     authenticate => 0x20,
  85                     shared => 0x80, # more than one person holds the entire private key
  86                   };
  87
  88 # see RFC 4880 section 4.3
  89 my $packet_types = { pubkey_enc_session => 1,
  90                      sig => 2,
  91                      symkey_enc_session => 3,
  92                      onepass_sig => 4,
  93                      seckey => 5,
  94                      pubkey => 6,
  95                      sec_subkey => 7,
  96                      compressed_data => 8,
  97                      symenc_data => 9,
  98                      marker => 10,
  99                      literal => 11,
 100                      trust => 12,
 101                      uid => 13,
 102                      pub_subkey => 14,
 103                      uat => 17,
 104                      symenc_w_integrity => 18,
 105                      mdc => 19,
 106                    };
 107
 108 # see RFC 4880 section 5.2.1
 109 my $sig_types = { binary_doc => 0x00,
 110                   text_doc => 0x01,
 111                   standalone => 0x02,
 112                   generic_certification => 0x10,
 113                   persona_certification => 0x11,
 114                   casual_certification => 0x12,
 115                   positive_certification => 0x13,
 116                   subkey_binding => 0x18,
 117                   primary_key_binding => 0x19,
 118                   key_signature => 0x1f,
 119                   key_revocation => 0x20,
 120                   subkey_revocation => 0x28,
 121                   certification_revocation => 0x30,
 122                   timestamp => 0x40,
 123                   thirdparty => 0x50,
 124                 };
 125
 126
 127 # see RFC 4880 section 5.2.3.1
 128 my $subpacket_types = { sig_creation_time => 2,
 129                         sig_expiration_time => 3,
 130                         exportable => 4,
 131                         trust_sig => 5,
 132                         regex => 6,
 133                         revocable => 7,
 134                         key_expiration_time => 9,
 135                         preferred_cipher => 11,
 136                         revocation_key => 12,
 137                         issuer => 16,
 138                         notation => 20,
 139                         preferred_digest => 21,
 140                         preferred_compression => 22,
 141                         keyserver_prefs => 23,
 142                         preferred_keyserver => 24,
 143                         primary_uid => 25,
 144                         policy_uri => 26,
 145                         usage_flags => 27,
 146                         signers_uid => 28,
 147                         revocation_reason => 29,
 148                         features => 30,
 149                         signature_target => 31,
 150                         embedded_signature => 32,
 151                        };
 152
 153 # bitstring (see RFC 4880 section 5.2.3.24)
 154 my $features = { mdc => 0x01
 155                };
 156
 157 # bitstring (see RFC 4880 5.2.3.17)
 158 my $keyserver_prefs = { nomodify => 0x80
 159                       };
 160
 161 ###### end lookup tables ######
 162
 163 # FIXME: if we want to be able to interpret openpgp data as well as
 164 # produce it, we need to produce key/value-swapped lookup tables as well.
 165
 166
 167 ########### Math/Utility Functions ##############
 168
 169
 170 # see the bottom of page 43 of RFC 4880
 171 sub simple_checksum {
 172   my $bytes = shift;
 173
 174   return unpack("%32W*",$bytes) % 65536;
 175 }
 176
 177 # calculate the multiplicative inverse of a mod b this is euclid's
 178 # extended algorithm.  For more information see:
 179 # http://en.wikipedia.org/wiki/Extended_Euclidean_algorithm the
 180 # arguments here should be Crypt::OpenSSL::Bignum objects.  $a should
 181 # be the larger of the two values, and the two values should be
 182 # coprime.
 183
 184 sub modular_multi_inverse {
 185   my $a = shift;
 186   my $b = shift;
 187
 188
 189   my $origdivisor = $b->copy();
 190
 191   my $ctx = Crypt::OpenSSL::Bignum::CTX->new();
 192   my $x = Crypt::OpenSSL::Bignum->zero();
 193   my $y = Crypt::OpenSSL::Bignum->one();
 194   my $lastx = Crypt::OpenSSL::Bignum->one();
 195   my $lasty = Crypt::OpenSSL::Bignum->zero();
 196
 197   my $finalquotient;
 198   my $finalremainder;
 199
 200   while (! $b->is_zero()) {
 201     my ($quotient, $remainder) = $a->div($b, $ctx);
 202
 203     $a = $b;
 204     $b = $remainder;
 205
 206     my $temp = $x;
 207     $x = $lastx->sub($quotient->mul($x, $ctx));
 208     $lastx = $temp;
 209
 210     $temp = $y;
 211     $y = $lasty->sub($quotient->mul($y, $ctx));
 212     $lasty = $temp;
 213   }
 214
 215   if (!$a->is_one()) {
 216     die "did this math wrong.\n";
 217   }
 218
 219   # let's make sure that we return a positive value because RFC 4880,
 220   # section 3.2 only allows unsigned values:
 221
 222   ($finalquotient, $finalremainder) = $lastx->add($origdivisor)->div($origdivisor, $ctx);
 223
 224   return $finalremainder;
 225 }
 226
 227
 228 ############ OpenPGP formatting functions ############
 229
 230 # make an old-style packet out of the given packet type and body.
 231 # old-style  (see RFC 4880 section 4.2)
 232 sub make_packet {
 233   my $type = shift;
 234   my $body = shift;
 235   my $options = shift;
 236
 237   my $len = length($body);
 238   my $pseudolen = $len;
 239
 240   # if the caller wants to use at least N octets of packet length,
 241   # pretend that we're using that many.
 242   if (defined $options && defined $options->{'packet_length'}) {
 243       $pseudolen = 2**($options->{'packet_length'} * 8) - 1;
 244   }
 245   if ($pseudolen < $len) {
 246       $pseudolen = $len;
 247   }
 248
 249   my $lenbytes;
 250   my $lencode;
 251
 252   if ($pseudolen < 2**8) {
 253     $lenbytes = $old_format_packet_lengths->{one};
 254     $lencode = 'C';
 255   } elsif ($pseudolen < 2**16) {
 256     $lenbytes = $old_format_packet_lengths->{two};
 257     $lencode = 'n';
 258   } elsif ($pseudolen < 2**31) {
 259     ## not testing against full 32 bits because i don't want to deal
 260     ## with potential overflow.
 261     $lenbytes = $old_format_packet_lengths->{four};
 262     $lencode = 'N';
 263   } else {
 264     ## what the hell do we do here?
 265     $lenbytes = $old_format_packet_lengths->{indeterminate};
 266     $lencode = '';
 267   }
 268
 269   return pack('C'.$lencode, 0x80 + ($type * 4) + $lenbytes, $len).
 270     $body;
 271 }
 272
 273
 274 # takes a Crypt::OpenSSL::Bignum, returns it formatted as OpenPGP MPI
 275 # (RFC 4880 section 3.2)
 276 sub mpi_pack {
 277   my $num = shift;
 278
 279   my $val = $num->to_bin();
 280   my $mpilen = length($val)*8;
 281
 282 # this is a kludgy way to get the number of significant bits in the
 283 # first byte:
 284   my $bitsinfirstbyte = length(sprintf("%b", ord($val)));
 285
 286   $mpilen -= (8 - $bitsinfirstbyte);
 287
 288   return pack('n', $mpilen).$val;
 289 }
 290
 291 # pull an OpenPGP-specified MPI off of a given stream.
 292 sub read_mpi {
 293   my $instr = shift;
 294
 295   my $bitlen;
 296   read($instr, $bitlen, 2) or die "could not read MPI length.\n";
 297   $bitlen = unpack('n', $bitlen);
 298
 299   my $ret;
 300   read($instr, $ret, ($bitlen + 7)/8) or die "could not read MPI body.\n";
 301   return Crypt::OpenSSL::Bignum->new_from_bin($ret);
 302 }
 303
 304
 305 # FIXME: genericize these to accept either RSA or DSA keys:
 306 sub make_rsa_pub_key_body {
 307   my $key = shift;
 308   my $timestamp = shift;
 309
 310   my ($n, $e) = $key->get_key_parameters();
 311
 312   return
 313     pack('CN', 4, $timestamp).
 314       pack('C', $asym_algos->{rsa}).
 315         mpi_pack($n).
 316           mpi_pack($e);
 317 }
 318
 319 sub make_rsa_sec_key_body {
 320   my $key = shift;
 321   my $timestamp = shift;
 322
 323   # we're not using $a and $b, but we need them to get to $c.
 324   my ($n, $e, $d, $p, $q) = $key->get_key_parameters();
 325
 326   my $c3 = modular_multi_inverse($p, $q);
 327
 328   my $secret_material = mpi_pack($d).
 329     mpi_pack($p).
 330       mpi_pack($q).
 331         mpi_pack($c3);
 332
 333   # according to Crypt::OpenSSL::RSA, the closest value we can get out
 334   # of get_key_parameters is 1/q mod p; but according to sec 5.5.3 of
 335   # RFC 4880, we're actually looking for u, the multiplicative inverse
 336   # of p, mod q.  This is why we're calculating the value directly
 337   # with modular_multi_inverse.
 338
 339   return
 340     pack('CN', 4, $timestamp).
 341       pack('C', $asym_algos->{rsa}).
 342         mpi_pack($n).
 343           mpi_pack($e).
 344             pack('C', 0). # seckey material is not encrypted -- see RFC 4880 sec 5.5.3
 345               $secret_material.
 346                 pack('n', simple_checksum($secret_material));
 347 }
 348
 349 # expects an RSA key (public or private) and a timestamp
 350 sub fingerprint {
 351   my $key = shift;
 352   my $timestamp = shift;
 353
 354   my $rsabody = make_rsa_pub_key_body($key, $timestamp);
 355
 356   return Digest::SHA1::sha1(pack('Cn', 0x99, length($rsabody)).$rsabody);
 357 }
 358
 359
 360 # FIXME: handle DSA keys as well!
 361 sub pem2openpgp {
 362   my $rsa = shift;
 363   my $uid = shift;
 364   my $args = shift;
 365
 366   $rsa->use_sha1_hash();
 367
 368   # see page 22 of RFC 4880 for why i think this is the right padding
 369   # choice to use:
 370   $rsa->use_pkcs1_padding();
 371
 372   if (! $rsa->check_key()) {
 373     die "key does not check";
 374   }
 375
 376   my $version = pack('C', 4);
 377   # strong assertion of identity:
 378   my $sigtype = pack('C', $sig_types->{positive_certification});
 379   # RSA
 380   my $pubkey_algo = pack('C', $asym_algos->{rsa});
 381   # SHA1
 382   my $hash_algo = pack('C', $digests->{sha1});
 383
 384   # FIXME: i'm worried about generating a bazillion new OpenPGP
 385   # certificates from the same key, which could easily happen if you run
 386   # this script more than once against the same key (because the
 387   # timestamps will differ).  How can we prevent this?
 388
 389   # this environment variable (if set) overrides the current time, to
 390   # be able to create a standard key?  If we read the key from a file
 391   # instead of stdin, should we use the creation time on the file?
 392   my $timestamp = 0;
 393   if (defined $args->{timestamp}) {
 394     $timestamp = ($args->{timestamp} + 0);
 395   } else {
 396     $timestamp = time();
 397   }
 398
 399   my $creation_time_packet = pack('CCN', 5, $subpacket_types->{sig_creation_time}, $timestamp);
 400
 401
 402   my $flags = 0;
 403   if (! defined $args->{usage_flags}) {
 404     $flags = $usage_flags->{certify};
 405   } else {
 406     my @ff = split(",", $args->{usage_flags});
 407     foreach my $f (@ff) {
 408       if (! defined $usage_flags->{$f}) {
 409         die "No such flag $f";
 410       }
 411       $flags |= $usage_flags->{$f};
 412     }
 413   }
 414
 415   my $usage_packet = pack('CCC', 2, $subpacket_types->{usage_flags}, $flags);
 416
 417
 418   # how should we determine how far off to set the expiration date?
 419   # default is no expiration.  Specify the timestamp in seconds from the
 420   # key creation.
 421   my $expiration_packet = '';
 422   if (defined $args->{expiration}) {
 423     my $expires_in = $args->{expiration} + 0;
 424     $expiration_packet = pack('CCN', 5, $subpacket_types->{key_expiration_time}, $expires_in);
 425   }
 426
 427
 428   # prefer AES-256, AES-192, AES-128, CAST5, 3DES:
 429   my $pref_sym_algos = pack('CCCCCCC', 6, $subpacket_types->{preferred_cipher},
 430                             $ciphers->{aes256},
 431                             $ciphers->{aes192},
 432                             $ciphers->{aes128},
 433                             $ciphers->{cast5},
 434                             $ciphers->{tripledes}
 435                            );
 436
 437   # prefer SHA-1, SHA-256, RIPE-MD/160
 438   my $pref_hash_algos = pack('CCCCC', 4, $subpacket_types->{preferred_digest},
 439                              $digests->{sha1},
 440                              $digests->{sha256},
 441                              $digests->{ripemd160}
 442                             );
 443
 444   # prefer ZLIB, BZip2, ZIP
 445   my $pref_zip_algos = pack('CCCCC', 4, $subpacket_types->{preferred_compression},
 446                             $zips->{zlib},
 447                             $zips->{bzip2},
 448                             $zips->{zip}
 449                            );
 450
 451   # we support the MDC feature:
 452   my $feature_subpacket = pack('CCC', 2, $subpacket_types->{features},
 453                                $features->{mdc});
 454
 455   # keyserver preference: only owner modify (???):
 456   my $keyserver_pref = pack('CCC', 2, $subpacket_types->{keyserver_prefs},
 457                             $keyserver_prefs->{nomodify});
 458
 459   my $subpackets_to_be_hashed =
 460     $creation_time_packet.
 461       $usage_packet.
 462         $expiration_packet.
 463           $pref_sym_algos.
 464             $pref_hash_algos.
 465               $pref_zip_algos.
 466                 $feature_subpacket.
 467                   $keyserver_pref;
 468
 469   my $subpacket_octets = pack('n', length($subpackets_to_be_hashed));
 470
 471   my $sig_data_to_be_hashed =
 472     $version.
 473       $sigtype.
 474         $pubkey_algo.
 475           $hash_algo.
 476             $subpacket_octets.
 477               $subpackets_to_be_hashed;
 478
 479   my $pubkey = make_rsa_pub_key_body($rsa, $timestamp);
 480   my $seckey = make_rsa_sec_key_body($rsa, $timestamp);
 481
 482   # this is for signing.  it needs to be an old-style header with a
 483   # 2-packet octet count.
 484
 485   my $key_data = make_packet($packet_types->{pubkey}, $pubkey, {'packet_length'=>2});
 486
 487   # take the last 8 bytes of the fingerprint as the keyid:
 488   my $keyid = substr(fingerprint($rsa, $timestamp), 20 - 8, 8);
 489
 490   # the v4 signature trailer is:
 491
 492   # version number, literal 0xff, and then a 4-byte count of the
 493   # signature data itself.
 494   my $trailer = pack('CCN', 4, 0xff, length($sig_data_to_be_hashed));
 495
 496   my $uid_data =
 497     pack('CN', 0xb4, length($uid)).
 498       $uid;
 499
 500   my $datatosign =
 501     $key_data.
 502       $uid_data.
 503         $sig_data_to_be_hashed.
 504           $trailer;
 505
 506   my $data_hash = Digest::SHA1::sha1_hex($datatosign);
 507
 508   my $issuer_packet = pack('CCa8', 9, $subpacket_types->{issuer}, $keyid);
 509
 510   my $sig = Crypt::OpenSSL::Bignum->new_from_bin($rsa->sign($datatosign));
 511
 512   my $sig_body =
 513     $sig_data_to_be_hashed.
 514       pack('n', length($issuer_packet)).
 515         $issuer_packet.
 516           pack('n', hex(substr($data_hash, 0, 4))).
 517             mpi_pack($sig);
 518
 519   return
 520     make_packet($packet_types->{seckey}, $seckey).
 521       make_packet($packet_types->{uid}, $uid).
 522         make_packet($packet_types->{sig}, $sig_body);
 523 }
 524
 525
 526 sub openpgp2ssh {
 527   my $instr = shift;
 528   my $fpr = shift;
 529
 530   my $packettag;
 531   my $dummy;
 532   my $tag;
 533
 534   while (! eof($instr)) {
 535     read($instr, $packettag, 1);
 536     $packettag = ord($packettag);
 537
 538     my $packetlen;
 539     if ( ! (0x80 & $packettag)) {
 540       die "This is not an OpenPGP packet\n";
 541     }
 542     if (0x40 & $packettag) {
 543       $tag = (0x3f & $packettag);
 544       my $nextlen = 0;
 545       read($instr, $nextlen, 1);
 546       $nextlen = ord($nextlen);
 547       if ($nextlen < 192) {
 548         $packetlen = $nextlen;
 549       } elsif ($nextlen < 224) {
 550         my $newoct;
 551         read($instr, $newoct, 1);
 552         $newoct = ord($newoct);
 553         $packetlen = (($nextlen - 192) << 8) + ($newoct) + 192;
 554       } elsif ($nextlen == 255) {
 555         read($instr, $nextlen, 4);
 556         $packetlen = unpack('N', $nextlen);
 557       } else {
 558         # packet length is undefined.
 559       }
 560     } else {
 561       my $lentype;
 562       $lentype = 0x03 & $packettag;
 563       $tag = ( 0x3c & $packettag ) >> 2;
 564       if ($lentype == 0) {
 565         read($instr, $packetlen, 1) or die "could not read packet length\n";
 566         $packetlen = unpack('C', $packetlen);
 567       } elsif ($lentype == 1) {
 568         read($instr, $packetlen, 2) or die "could not read packet length\n";
 569         $packetlen = unpack('n', $packetlen);
 570       } elsif ($lentype == 2) {
 571         read($instr, $packetlen, 4) or die "could not read packet length\n";
 572         $packetlen = unpack('N', $packetlen);
 573       } else {
 574         # packet length is undefined.
 575       }
 576     }
 577
 578     if (! defined($packetlen)) {
 579       die "Undefined packet lengths are not supported.\n";
 580     }
 581
 582     if ($tag == $packet_types->{pubkey} ||
 583         $tag == $packet_types->{pub_subkey} ||
 584         $tag == $packet_types->{seckey} ||
 585         $tag == $packet_types->{sec_subkey}) {
 586       printf(STDERR "Packet type %d\n", $tag);
 587
 588       my $ver;
 589       read($instr, $ver, 1) or die "could not read key version\n";
 590       $ver = ord($ver);
 591       if ($ver != 4) {
 592         printf(STDERR "We only work with version 4 keys.  This key appears to be version $ver.\n");
 593         read($instr, $dummy, $packetlen - 1) or die "Could not skip past this packet.\n";
 594       } else {
 595
 596         my $timestamp;
 597         read($instr, $timestamp, 4) or die "could not read key timestamp.\n";
 598         $timestamp = unpack('N', $timestamp);
 599
 600         my $algo;
 601         read($instr, $algo, 1) or die "could not read key algorithm.\n";
 602         $algo = ord($algo);
 603         if ($algo != $asym_algos->{rsa}) {
 604           printf(STDERR "We only support RSA keys (this key used algorithm %d).\n", $algo);
 605           read($instr, $dummy, $packetlen - 6) or die "Could not skip past this packet.\n";
 606         } else {
 607           ## we have an RSA key.
 608           my $modulus = read_mpi($instr);
 609           my $exponent = read_mpi($instr);
 610
 611           my $pubkey = Crypt::OpenSSL::RSA->new_key_from_parameters($modulus, $exponent);
 612           my $foundfpr = fingerprint($pubkey, $timestamp);
 613
 614           printf(STDERR "key fpr: %s\n", Crypt::OpenSSL::Bignum->new_from_bin($foundfpr)->to_hex());
 615
 616           if ($tag == $packet_types->{seckey} ||
 617               $tag == $packet_types->{sec_subkey}) {
 618             die "Cannot deal with secret keys yet!\n";
 619           }
 620
 621         }
 622       }
 623     } else {
 624       read($instr, $dummy, $packetlen) or die "Could not skip past this packet!\n";
 625     }
 626   }
 627
 628   print $tag;
 629 }
 630
 631
 632 for (basename($0)) {
 633   if (/^pem2openpgp$/) {
 634     my $rsa;
 635     my $stdin;
 636     if (defined $ENV{PEM2OPENPGP_NEWKEY}) {
 637       $rsa = Crypt::OpenSSL::RSA->generate_key($ENV{PEM2OPENPGP_NEWKEY});
 638     } else {
 639       $stdin = do {
 640         local $/; # slurp!
 641         <STDIN>;
 642       };
 643
 644       $rsa = Crypt::OpenSSL::RSA->new_private_key($stdin);
 645     }
 646
 647     my $uid = shift;
 648
 649     # FIXME: fail if there is no given user ID; or should we default to
 650     # hostname_long() from Sys::Hostname::Long ?
 651
 652     print pem2openpgp($rsa,
 653                       $uid,
 654                       { timestamp => $ENV{PEM2OPENPGP_TIMESTAMP},
 655                         expiration => $ENV{PEM2OPENPGP_EXPIRATION},
 656                         usage_flags => $ENV{PEM2OPENPGP_USAGE_FLAGS},
 657                       }
 658                      );
 659   }
 660   elsif (/^openpgp2ssh$/) {
 661       my $fpr = shift;
 662       my $instream;
 663       open($instream,'-');
 664       binmode($instream, ":bytes");
 665       openpgp2ssh($instream, $fpr);
 666   }
 667   else {
 668     die "Unrecognized keytrans call.\n";
 669   }
 670 }
 671