/**
 * \file
 * <!--
 * This file is part of BeRTOS.
 *
 * Bertos is free software; you can redistribute it and/or modify
 * it under the terms of the GNU General Public License as published by
 * the Free Software Foundation; either version 2 of the License, or
 * (at your option) any later version.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with this program; if not, write to the Free Software
 * Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA  02110-1301  USA
 *
 * As a special exception, you may use this file as part of a free software
 * library without restriction.  Specifically, if other files instantiate
 * templates or use macros or inline functions from this file, or you compile
 * this file and link it with other files to produce an executable, this
 * file does not by itself cause the resulting executable to be covered by
 * the GNU General Public License.  This exception does not however
 * invalidate any other reasons why the executable file might be covered by
 * the GNU General Public License.
 *
 * Copyright 2007, 2008 Develer S.r.l. (http://www.develer.com/)
 *
 * -->
 *
 * \brief ARM context switch
 *
 *
 * \author Stefano Fedrigo <aleph@develer.com>
 * \author Francesco Sacchi <batt@develer.com>
 */

/* void asm_switch_context(void **new_sp [r0], void **save_sp [r1]) */
.globl asm_switch_context
asm_switch_context:
	mrs	r2, cpsr               /* Save status. */

	stmfd	sp!, {r2, r4-r11, lr}  /* Save registers. */

	str     sp, [r1]               /* Save old stack pointer. */
	ldr	sp, [r0]               /* Load new stack pointer */

	ldmfd	sp!, {r2, r4-r11, lr}  /* Load new registers. */
	msr	cpsr, r2               /* restore flags reg. */

	mov	pc, lr


/* proc_entry trampoline needed because ARM does not pop return addresses
from the stack, but uses lr instead.*/
.globl asm_proc_entry
asm_proc_entry:
	mov	lr, pc
	/* In r11 we have the real process entry point as set up by CPU_CREATE_NEW_STACK */
	bx	r11
	bl	proc_exit