src/keytrans/pem2openpgp

   1 #!/usr/bin/perl -w -T
   2
   3 # pem2openpgp: take a PEM-encoded RSA private-key on standard input, a
   4 # User ID as the first argument, and generate an OpenPGP certificate
   5 # from it.
   6
   7 # Usage:
   8
   9 # pem2openpgp 'ssh://'$(hostname -f) < /etc/ssh/ssh_host_rsa_key | gpg --import
  10
  11 # Authors:
  12 #  Jameson Rollins <jrollins@finestructure.net>
  13 #  Daniel Kahn Gillmor <dkg@fifthhorseman.net>
  14
  15 # Started on: 2009-01-07 02:01:19-0500
  16
  17 # License: GPL v3 or later (we may need to adjust this given that this
  18 # connects to OpenSSL via perl)
  19
  20 use strict;
  21 use warnings;
  22 use Crypt::OpenSSL::RSA;
  23 use Crypt::OpenSSL::Bignum;
  24 use Digest::SHA1;
  25 use MIME::Base64;
  26
  27 ## make sure all length() and substr() calls use bytes only:
  28 use bytes;
  29
  30 my $uid = shift;
  31
  32 # FIXME: fail if there is no given user ID; or should we default to
  33 # hostname_long() from Sys::Hostname::Long ?
  34
  35 # make an old-style packet out of the given packet type and body.
  36 # old-style  (see RFC 4880 section 4.2)
  37 sub make_packet {
  38   my $type = shift;
  39   my $body = shift;
  40
  41   my $len = length($body);
  42
  43   my $lenbytes;
  44   my $lencode;
  45
  46   if ($len < 2**8) {
  47     $lenbytes = 0;
  48     $lencode = 'C';
  49   } elsif ($len < 2**16) {
  50     $lenbytes = 1;
  51     $lencode = 'n';
  52   } elsif ($len < 2**31) {
  53     ## not testing against full 32 bits because i don't want to deal
  54     ## with potential overflow.
  55     $lenbytes = 2;
  56     $lencode = 'N';
  57   } else {
  58     ## what the hell do we do here?
  59     $lenbytes = 3;
  60     $lencode = '';
  61   }
  62
  63   return pack('C'.$lencode, 0x80 + ($type * 4) + $lenbytes, $len).
  64     $body;
  65 }
  66
  67
  68 # takes a Crypt::OpenSSL::Bignum, returns it formatted as OpenPGP MPI
  69 # (RFC 4880 section 3.2)
  70 sub mpi_pack {
  71   my $num = shift;
  72
  73   my $val = $num->to_bin();
  74   my $mpilen = length($val)*8;
  75
  76 # this is a kludgy way to get the number of significant bits in the
  77 # first byte:
  78   my $bitsinfirstbyte = length(sprintf("%b", ord($val)));
  79
  80   $mpilen -= (8 - $bitsinfirstbyte);
  81
  82   return pack('n', $mpilen).$val;
  83 }
  84
  85 # FIXME: genericize this to accept either RSA or DSA keys:
  86 sub make_rsa_pub_key_body {
  87   my $key = shift;
  88   my $timestamp = shift;
  89
  90   my ($n, $e) = $key->get_key_parameters();
  91
  92   return
  93     pack('CN', 4, $timestamp).
  94       pack('C', 1). # RSA
  95         mpi_pack($n).
  96           mpi_pack($e);
  97
  98 }
  99
 100 # expects an RSA key (public or private) and a timestamp
 101 sub fingerprint {
 102   my $key = shift;
 103   my $timestamp = shift;
 104
 105   my $rsabody = make_rsa_pub_key_body($key, $timestamp);
 106
 107   return Digest::SHA1::sha1(pack('Cn', 0x99, length($rsabody)).$rsabody);
 108 }
 109
 110 # FIXME: make tables of relevant identifiers: digest algorithms,
 111 # ciphers, asymmetric crypto, packet types, subpacket types, signature
 112 # types.  As these are created, replace the opaque numbers below with
 113 # semantically-meaningful code.
 114
 115 # see RFC 4880 section 5.2.3.21
 116 my $usage_flags = { certify => 0x01,
 117                     sign => 0x02,
 118                     encrypt_comms => 0x04,
 119                     encrypt_storage => 0x08,
 120                     encrypt => 0x0c, ## both comms and storage
 121                     split => 0x10, # the private key is split via secret sharing
 122                     authenticate => 0x20,
 123                     shared => 0x80, # more than one person holds the entire private key
 124                   };
 125
 126
 127 # we're just not dealing with newline business right now.  slurp in
 128 # the whole file.
 129 undef $/;
 130 my $buf = <STDIN>;
 131
 132
 133 my $rsa = Crypt::OpenSSL::RSA->new_private_key($buf);
 134
 135 $rsa->use_sha1_hash();
 136 $rsa->use_no_padding();
 137
 138 if (! $rsa->check_key()) {
 139   die "key does not check";
 140 }
 141
 142 my $version = pack('C', 4);
 143 # strong assertion of identity:
 144 my $sigtype = pack('C', 0x13);
 145 # RSA
 146 my $pubkey_algo = pack('C', 1);
 147 # SHA1
 148 my $hash_algo = pack('C', 2);
 149
 150 # FIXME: i'm worried about generating a bazillion new OpenPGP
 151 # certificates from the same key, which could easily happen if you run
 152 # this script more than once against the same key.  How can we prevent
 153 # this?
 154
 155 # could an environment variable (if set) override the current time?
 156 my $timestamp = time();
 157
 158 my $creation_time_packet = pack('CCN', 5, 2, $timestamp);
 159
 160
 161 # FIXME: HARDCODED: what if someone wants to select a different set of
 162 # usage flags?  For now, we do only authentication.
 163 my $flags = $usage_flags->{authenticate};
 164 my $usage_packet = pack('CCC', 2, 27, $flags);
 165
 166
 167 # FIXME: HARDCODED: how should we determine how far off to set the
 168 # expiration date?  default is to expire in 2 days, which is insanely
 169 # short (but good for testing).
 170 my $expires_in = 86400*2;
 171 my $expiration_packet = pack('CCN', 5, 9, $expires_in);
 172
 173
 174 # prefer AES-256, AES-192, AES-128, CAST5, 3DES:
 175 my $pref_sym_algos = pack('CCCCCCC', 6, 11, 9, 8, 7, 3, 2);
 176
 177 # prefer SHA-1, SHA-256, RIPE-MD/160
 178 my $pref_hash_algos = pack('CCCCC', 4, 21, 2, 8, 3);
 179
 180 # prefer ZLIB, BZip2, ZIP
 181 my $pref_zip_algos = pack('CCCCC', 4, 22, 2, 3, 1);
 182
 183 # we support the MDC feature:
 184 my $features = pack('CCC', 2, 30, 1);
 185
 186 # keyserver preference: only owner modify (???):
 187 my $keyserver_pref = pack('CCC', 2, 23, 0x80);
 188
 189 my $subpackets_to_be_hashed =
 190   $creation_time_packet.
 191   $usage_packet.
 192   $expiration_packet.
 193   $pref_sym_algos.
 194   $pref_hash_algos.
 195   $pref_zip_algos.
 196   $features.
 197   $keyserver_pref;
 198
 199 my $subpacket_octets = pack('n', length($subpackets_to_be_hashed));
 200
 201 my $sig_data_to_be_hashed =
 202   $version.
 203   $sigtype.
 204   $pubkey_algo.
 205   $hash_algo.
 206   $subpacket_octets.
 207   $subpackets_to_be_hashed;
 208
 209 my $pubkey = make_rsa_pub_key_body($rsa, $timestamp);
 210
 211 #open(KEYFILE, "</home/wt215/gpg-test/key-data");
 212 my $key_data = make_packet(6, $pubkey);
 213
 214 # take the last 8 bytes of the fingerprint as the keyid:
 215 my $keyid = substr(fingerprint($rsa, $timestamp), 20 - 8, 8);
 216
 217 # the v4 signature trailer is:
 218
 219 # version number, literal 0xff, and then a 4-byte count of the
 220 # signature data itself.
 221 my $trailer = pack('CCN', 4, 0xff, length($sig_data_to_be_hashed));
 222
 223 my $uid_data =
 224   pack('CN', 0xb4, length($uid)).
 225   $uid;
 226
 227 my $datatosign =
 228   $key_data.
 229   $uid_data.
 230   $sig_data_to_be_hashed.
 231   $trailer;
 232
 233 my $data_hash = Digest::SHA1::sha1_hex($datatosign);
 234
 235
 236 my $issuer_packet = pack('CCa8', 9, 16, $keyid);
 237
 238 my $sig = Crypt::OpenSSL::Bignum->new_from_bin($rsa->sign($datatosign));
 239
 240 my $sig_body =
 241   $sig_data_to_be_hashed.
 242   pack('n', length($issuer_packet)).
 243   $issuer_packet.
 244   pack('n', hex(substr($data_hash, 0, 4))).
 245   mpi_pack($sig);
 246
 247 print
 248   make_packet(6, $pubkey).
 249   make_packet(13, $uid).
 250   make_packet(2, $sig_body);
 251
 252