src/keytrans/pem2openpgp

   1 #!/usr/bin/perl -w -T
   2
   3 # pem2openpgp: take a PEM-encoded RSA private-key on standard input, a
   4 # User ID as the first argument, and generate an OpenPGP secret key
   5 # and certificate from it.
   6
   7 # WARNING: the secret key material *will* appear on stdout (albeit in
   8 # OpenPGP form) -- if you redirect stdout to a file, make sure the
   9 # permissions on that file are appropriately locked down!
  10
  11 # Usage:
  12
  13 # pem2openpgp 'ssh://'$(hostname -f) < /etc/ssh/ssh_host_rsa_key | gpg --import
  14
  15 # Authors:
  16 #  Jameson Rollins <jrollins@finestructure.net>
  17 #  Daniel Kahn Gillmor <dkg@fifthhorseman.net>
  18
  19 # Started on: 2009-01-07 02:01:19-0500
  20
  21 # License: GPL v3 or later (we may need to adjust this given that this
  22 # connects to OpenSSL via perl)
  23
  24 use strict;
  25 use warnings;
  26 use File::Basename;
  27 use Crypt::OpenSSL::RSA;
  28 use Crypt::OpenSSL::Bignum;
  29 use Crypt::OpenSSL::Bignum::CTX;
  30 use Digest::SHA1;
  31 use MIME::Base64;
  32
  33 ## make sure all length() and substr() calls use bytes only:
  34 use bytes;
  35
  36 my $old_format_packet_lengths = { one => 0,
  37                                   two => 1,
  38                                   four => 2,
  39                                   indeterminate => 3,
  40 };
  41
  42 # see RFC 4880 section 9.1 (ignoring deprecated algorithms for now)
  43 my $asym_algos = { rsa => 1,
  44                    elgamal => 16,
  45                    dsa => 17,
  46                    };
  47
  48 # see RFC 4880 section 9.2
  49 my $ciphers = { plaintext => 0,
  50                 idea => 1,
  51                 tripledes => 2,
  52                 cast5 => 3,
  53                 blowfish => 4,
  54                 aes128 => 7,
  55                 aes192 => 8,
  56                 aes256 => 9,
  57                 twofish => 10,
  58               };
  59
  60 # see RFC 4880 section 9.3
  61 my $zips = { uncompressed => 0,
  62              zip => 1,
  63              zlib => 2,
  64              bzip2 => 3,
  65            };
  66
  67 # see RFC 4880 section 9.4
  68 my $digests = { md5 => 1,
  69                 sha1 => 2,
  70                 ripemd160 => 3,
  71                 sha256 => 8,
  72                 sha384 => 9,
  73                 sha512 => 10,
  74                 sha224 => 11,
  75               };
  76
  77 # see RFC 4880 section 5.2.3.21
  78 my $usage_flags = { certify => 0x01,
  79                     sign => 0x02,
  80                     encrypt_comms => 0x04,
  81                     encrypt_storage => 0x08,
  82                     encrypt => 0x0c, ## both comms and storage
  83                     split => 0x10, # the private key is split via secret sharing
  84                     authenticate => 0x20,
  85                     shared => 0x80, # more than one person holds the entire private key
  86                   };
  87
  88 # see RFC 4880 section 4.3
  89 my $packet_types = { pubkey_enc_session => 1,
  90                      sig => 2,
  91                      symkey_enc_session => 3,
  92                      onepass_sig => 4,
  93                      seckey => 5,
  94                      pubkey => 6,
  95                      sec_subkey => 7,
  96                      compressed_data => 8,
  97                      symenc_data => 9,
  98                      marker => 10,
  99                      literal => 11,
 100                      trust => 12,
 101                      uid => 13,
 102                      pub_subkey => 14,
 103                      uat => 17,
 104                      symenc_w_integrity => 18,
 105                      mdc => 19,
 106                    };
 107
 108 # see RFC 4880 section 5.2.1
 109 my $sig_types = { binary_doc => 0x00,
 110                   text_doc => 0x01,
 111                   standalone => 0x02,
 112                   generic_certification => 0x10,
 113                   persona_certification => 0x11,
 114                   casual_certification => 0x12,
 115                   positive_certification => 0x13,
 116                   subkey_binding => 0x18,
 117                   primary_key_binding => 0x19,
 118                   key_signature => 0x1f,
 119                   key_revocation => 0x20,
 120                   subkey_revocation => 0x28,
 121                   certification_revocation => 0x30,
 122                   timestamp => 0x40,
 123                   thirdparty => 0x50,
 124                 };
 125
 126
 127 # see RFC 4880 section 5.2.3.1
 128 my $subpacket_types = { sig_creation_time => 2,
 129                         sig_expiration_time => 3,
 130                         exportable => 4,
 131                         trust_sig => 5,
 132                         regex => 6,
 133                         revocable => 7,
 134                         key_expiration_time => 9,
 135                         preferred_cipher => 11,
 136                         revocation_key => 12,
 137                         issuer => 16,
 138                         notation => 20,
 139                         preferred_digest => 21,
 140                         preferred_compression => 22,
 141                         keyserver_prefs => 23,
 142                         preferred_keyserver => 24,
 143                         primary_uid => 25,
 144                         policy_uri => 26,
 145                         usage_flags => 27,
 146                         signers_uid => 28,
 147                         revocation_reason => 29,
 148                         features => 30,
 149                         signature_target => 31,
 150                         embedded_signature => 32,
 151                        };
 152
 153 # bitstring (see RFC 4880 section 5.2.3.24)
 154 my $features = { mdc => 0x01
 155                };
 156
 157 # bitstring (see RFC 4880 5.2.3.17)
 158 my $keyserver_prefs = { nomodify => 0x80
 159                       };
 160
 161 ###### end lookup tables ######
 162
 163 # FIXME: if we want to be able to interpret openpgp data as well as
 164 # produce it, we need to produce key/value-swapped lookup tables as well.
 165
 166
 167 ########### Math/Utility Functions ##############
 168
 169
 170 # see the bottom of page 43 of RFC 4880
 171 sub simple_checksum {
 172   my $bytes = shift;
 173
 174   return unpack("%32W*",$bytes) % 65536;
 175 }
 176
 177 # calculate the multiplicative inverse of a mod b this is euclid's
 178 # extended algorithm.  For more information see:
 179 # http://en.wikipedia.org/wiki/Extended_Euclidean_algorithm the
 180 # arguments here should be Crypt::OpenSSL::Bignum objects.  $a should
 181 # be the larger of the two values, and the two values should be
 182 # coprime.
 183
 184 sub modular_multi_inverse {
 185   my $a = shift;
 186   my $b = shift;
 187
 188
 189   my $origdivisor = $b->copy();
 190
 191   my $ctx = Crypt::OpenSSL::Bignum::CTX->new();
 192   my $x = Crypt::OpenSSL::Bignum->zero();
 193   my $y = Crypt::OpenSSL::Bignum->one();
 194   my $lastx = Crypt::OpenSSL::Bignum->one();
 195   my $lasty = Crypt::OpenSSL::Bignum->zero();
 196
 197   my $finalquotient;
 198   my $finalremainder;
 199
 200   while (! $b->is_zero()) {
 201     my ($quotient, $remainder) = $a->div($b, $ctx);
 202
 203     $a = $b;
 204     $b = $remainder;
 205
 206     my $temp = $x;
 207     $x = $lastx->sub($quotient->mul($x, $ctx));
 208     $lastx = $temp;
 209
 210     $temp = $y;
 211     $y = $lasty->sub($quotient->mul($y, $ctx));
 212     $lasty = $temp;
 213   }
 214
 215   if (!$a->is_one()) {
 216     die "did this math wrong.\n";
 217   }
 218
 219   # let's make sure that we return a positive value because RFC 4880,
 220   # section 3.2 only allows unsigned values:
 221
 222   ($finalquotient, $finalremainder) = $lastx->add($origdivisor)->div($origdivisor, $ctx);
 223
 224   return $finalremainder;
 225 }
 226
 227
 228 ############ OpenPGP formatting functions ############
 229
 230 # make an old-style packet out of the given packet type and body.
 231 # old-style  (see RFC 4880 section 4.2)
 232 sub make_packet {
 233   my $type = shift;
 234   my $body = shift;
 235   my $options = shift;
 236
 237   my $len = length($body);
 238   my $pseudolen = $len;
 239
 240   # if the caller wants to use at least N octets of packet length,
 241   # pretend that we're using that many.
 242   if (defined $options && defined $options->{'packet_length'}) {
 243       $pseudolen = 2**($options->{'packet_length'} * 8) - 1;
 244   }
 245   if ($pseudolen < $len) {
 246       $pseudolen = $len;
 247   }
 248
 249   my $lenbytes;
 250   my $lencode;
 251
 252   if ($pseudolen < 2**8) {
 253     $lenbytes = $old_format_packet_lengths->{one};
 254     $lencode = 'C';
 255   } elsif ($pseudolen < 2**16) {
 256     $lenbytes = $old_format_packet_lengths->{two};
 257     $lencode = 'n';
 258   } elsif ($pseudolen < 2**31) {
 259     ## not testing against full 32 bits because i don't want to deal
 260     ## with potential overflow.
 261     $lenbytes = $old_format_packet_lengths->{four};
 262     $lencode = 'N';
 263   } else {
 264     ## what the hell do we do here?
 265     $lenbytes = $old_format_packet_lengths->{indeterminate};
 266     $lencode = '';
 267   }
 268
 269   return pack('C'.$lencode, 0x80 + ($type * 4) + $lenbytes, $len).
 270     $body;
 271 }
 272
 273
 274 # takes a Crypt::OpenSSL::Bignum, returns it formatted as OpenPGP MPI
 275 # (RFC 4880 section 3.2)
 276 sub mpi_pack {
 277   my $num = shift;
 278
 279   my $val = $num->to_bin();
 280   my $mpilen = length($val)*8;
 281
 282 # this is a kludgy way to get the number of significant bits in the
 283 # first byte:
 284   my $bitsinfirstbyte = length(sprintf("%b", ord($val)));
 285
 286   $mpilen -= (8 - $bitsinfirstbyte);
 287
 288   return pack('n', $mpilen).$val;
 289 }
 290
 291 # FIXME: genericize these to accept either RSA or DSA keys:
 292 sub make_rsa_pub_key_body {
 293   my $key = shift;
 294   my $timestamp = shift;
 295
 296   my ($n, $e) = $key->get_key_parameters();
 297
 298   return
 299     pack('CN', 4, $timestamp).
 300       pack('C', $asym_algos->{rsa}).
 301         mpi_pack($n).
 302           mpi_pack($e);
 303 }
 304
 305 sub make_rsa_sec_key_body {
 306   my $key = shift;
 307   my $timestamp = shift;
 308
 309   # we're not using $a and $b, but we need them to get to $c.
 310   my ($n, $e, $d, $p, $q) = $key->get_key_parameters();
 311
 312   my $c3 = modular_multi_inverse($p, $q);
 313
 314   my $secret_material = mpi_pack($d).
 315     mpi_pack($p).
 316       mpi_pack($q).
 317         mpi_pack($c3);
 318
 319   # according to Crypt::OpenSSL::RSA, the closest value we can get out
 320   # of get_key_parameters is 1/q mod p; but according to sec 5.5.3 of
 321   # RFC 4880, we're actually looking for u, the multiplicative inverse
 322   # of p, mod q.  This is why we're calculating the value directly
 323   # with modular_multi_inverse.
 324
 325   return
 326     pack('CN', 4, $timestamp).
 327       pack('C', $asym_algos->{rsa}).
 328         mpi_pack($n).
 329           mpi_pack($e).
 330             pack('C', 0). # seckey material is not encrypted -- see RFC 4880 sec 5.5.3
 331               $secret_material.
 332                 pack('n', simple_checksum($secret_material));
 333 }
 334
 335 # expects an RSA key (public or private) and a timestamp
 336 sub fingerprint {
 337   my $key = shift;
 338   my $timestamp = shift;
 339
 340   my $rsabody = make_rsa_pub_key_body($key, $timestamp);
 341
 342   return Digest::SHA1::sha1(pack('Cn', 0x99, length($rsabody)).$rsabody);
 343 }
 344
 345
 346 # FIXME: handle DSA keys as well!
 347 sub pem2openpgp {
 348   my $rsa = shift;
 349   my $uid = shift;
 350   my $args = shift;
 351
 352   $rsa->use_sha1_hash();
 353
 354   # see page 22 of RFC 4880 for why i think this is the right padding
 355   # choice to use:
 356   $rsa->use_pkcs1_padding();
 357
 358   if (! $rsa->check_key()) {
 359     die "key does not check";
 360   }
 361
 362   my $version = pack('C', 4);
 363   # strong assertion of identity:
 364   my $sigtype = pack('C', $sig_types->{positive_certification});
 365   # RSA
 366   my $pubkey_algo = pack('C', $asym_algos->{rsa});
 367   # SHA1
 368   my $hash_algo = pack('C', $digests->{sha1});
 369
 370   # FIXME: i'm worried about generating a bazillion new OpenPGP
 371   # certificates from the same key, which could easily happen if you run
 372   # this script more than once against the same key (because the
 373   # timestamps will differ).  How can we prevent this?
 374
 375   # this environment variable (if set) overrides the current time, to
 376   # be able to create a standard key?  If we read the key from a file
 377   # instead of stdin, should we use the creation time on the file?
 378   my $timestamp = 0;
 379   if (defined $args->{timestamp}) {
 380     $timestamp = ($args->{timestamp} + 0);
 381   } else {
 382     $timestamp = time();
 383   }
 384
 385   my $creation_time_packet = pack('CCN', 5, $subpacket_types->{sig_creation_time}, $timestamp);
 386
 387
 388   my $flags = 0;
 389   if (! defined $args->{usage_flags}) {
 390     $flags = $usage_flags->{certify};
 391   } else {
 392     my @ff = split(",", $args->{usage_flags});
 393     foreach my $f (@ff) {
 394       if (! defined $usage_flags->{$f}) {
 395         die "No such flag $f";
 396       }
 397       $flags |= $usage_flags->{$f};
 398     }
 399   }
 400
 401   my $usage_packet = pack('CCC', 2, $subpacket_types->{usage_flags}, $flags);
 402
 403
 404   # how should we determine how far off to set the expiration date?
 405   # default is no expiration.  Specify the timestamp in seconds from the
 406   # key creation.
 407   my $expiration_packet = '';
 408   if (defined $args->{expiration}) {
 409     my $expires_in = $args->{expiration} + 0;
 410     $expiration_packet = pack('CCN', 5, $subpacket_types->{key_expiration_time}, $expires_in);
 411   }
 412
 413
 414   # prefer AES-256, AES-192, AES-128, CAST5, 3DES:
 415   my $pref_sym_algos = pack('CCCCCCC', 6, $subpacket_types->{preferred_cipher},
 416                             $ciphers->{aes256},
 417                             $ciphers->{aes192},
 418                             $ciphers->{aes128},
 419                             $ciphers->{cast5},
 420                             $ciphers->{tripledes}
 421                            );
 422
 423   # prefer SHA-1, SHA-256, RIPE-MD/160
 424   my $pref_hash_algos = pack('CCCCC', 4, $subpacket_types->{preferred_digest},
 425                              $digests->{sha1},
 426                              $digests->{sha256},
 427                              $digests->{ripemd160}
 428                             );
 429
 430   # prefer ZLIB, BZip2, ZIP
 431   my $pref_zip_algos = pack('CCCCC', 4, $subpacket_types->{preferred_compression},
 432                             $zips->{zlib},
 433                             $zips->{bzip2},
 434                             $zips->{zip}
 435                            );
 436
 437   # we support the MDC feature:
 438   my $feature_subpacket = pack('CCC', 2, $subpacket_types->{features},
 439                                $features->{mdc});
 440
 441   # keyserver preference: only owner modify (???):
 442   my $keyserver_pref = pack('CCC', 2, $subpacket_types->{keyserver_prefs},
 443                             $keyserver_prefs->{nomodify});
 444
 445   my $subpackets_to_be_hashed =
 446     $creation_time_packet.
 447       $usage_packet.
 448         $expiration_packet.
 449           $pref_sym_algos.
 450             $pref_hash_algos.
 451               $pref_zip_algos.
 452                 $feature_subpacket.
 453                   $keyserver_pref;
 454
 455   my $subpacket_octets = pack('n', length($subpackets_to_be_hashed));
 456
 457   my $sig_data_to_be_hashed =
 458     $version.
 459       $sigtype.
 460         $pubkey_algo.
 461           $hash_algo.
 462             $subpacket_octets.
 463               $subpackets_to_be_hashed;
 464
 465   my $pubkey = make_rsa_pub_key_body($rsa, $timestamp);
 466   my $seckey = make_rsa_sec_key_body($rsa, $timestamp);
 467
 468   # this is for signing.  it needs to be an old-style header with a
 469   # 2-packet octet count.
 470
 471   my $key_data = make_packet($packet_types->{pubkey}, $pubkey, {'packet_length'=>2});
 472
 473   # take the last 8 bytes of the fingerprint as the keyid:
 474   my $keyid = substr(fingerprint($rsa, $timestamp), 20 - 8, 8);
 475
 476   # the v4 signature trailer is:
 477
 478   # version number, literal 0xff, and then a 4-byte count of the
 479   # signature data itself.
 480   my $trailer = pack('CCN', 4, 0xff, length($sig_data_to_be_hashed));
 481
 482   my $uid_data =
 483     pack('CN', 0xb4, length($uid)).
 484       $uid;
 485
 486   my $datatosign =
 487     $key_data.
 488       $uid_data.
 489         $sig_data_to_be_hashed.
 490           $trailer;
 491
 492   my $data_hash = Digest::SHA1::sha1_hex($datatosign);
 493
 494   my $issuer_packet = pack('CCa8', 9, $subpacket_types->{issuer}, $keyid);
 495
 496   my $sig = Crypt::OpenSSL::Bignum->new_from_bin($rsa->sign($datatosign));
 497
 498   my $sig_body =
 499     $sig_data_to_be_hashed.
 500       pack('n', length($issuer_packet)).
 501         $issuer_packet.
 502           pack('n', hex(substr($data_hash, 0, 4))).
 503             mpi_pack($sig);
 504
 505   return
 506     make_packet($packet_types->{seckey}, $seckey).
 507       make_packet($packet_types->{uid}, $uid).
 508         make_packet($packet_types->{sig}, $sig_body);
 509 }
 510
 511
 512
 513
 514 sub openpgp2ssh {
 515   my $instr = shift;
 516   my $fpr = shift;
 517
 518   my $packettag;
 519   read($instr, $packettag, 1);
 520   $packettag = ord($packettag);
 521
 522   my $packetlen;
 523   if ( ! (0x80 & $packettag)) {
 524     print STDERR "This is not an OpenPGP packet";
 525     exit 1;
 526   }
 527   if (0x40 & $packettag) {
 528     print STDERR "This is a new-style packet header";
 529     $tag = (0x3f & $packettag);
 530   } else {
 531     print STDERR "This is an old-style packet header";
 532     $lentype = 0x03 & $packettag;
 533     $tag = (0x3c & $packettag ) >> 2;
 534     if ($lentype == 0) {
 535       read($instr, $packetlen, 1);
 536       $packetlen = unpack('%C', $packetlen);
 537     } elsif ($lentype == 1) {
 538       read($instr, $packetlen, 2);
 539       $packetlen = unpack('%S', $packetlen);
 540     } elsif ($lentype == 2) {
 541       read($instr, $packetlen, 4);
 542       $packetlen = unpack('%L', $packetlen);
 543     }
 544   }
 545   printf(STDERR, "Packet is %d long\n", $packetlen);
 546
 547   print $packettag;
 548 }
 549
 550
 551 for (basename($0)) {
 552   if (/^pem2openpgp$/) {
 553
 554     my $rsa;
 555     my $stdin;
 556     if (defined $ENV{PEM2OPENPGP_NEWKEY}) {
 557       $rsa = Crypt::OpenSSL::RSA->generate_key($ENV{PEM2OPENPGP_NEWKEY});
 558     } else {
 559       $stdin = do {
 560         local $/; # slurp!
 561         <STDIN>;
 562       };
 563
 564       $rsa = Crypt::OpenSSL::RSA->new_private_key($stdin);
 565     }
 566
 567     my $uid = shift;
 568
 569     # FIXME: fail if there is no given user ID; or should we default to
 570     # hostname_long() from Sys::Hostname::Long ?
 571
 572     print pem2openpgp($rsa,
 573                       $uid,
 574                       { timestamp => $ENV{PEM2OPENPGP_TIMESTAMP},
 575                         expiration => $ENV{PEM2OPENPGP_EXPIRATION},
 576                         usage_flags => $ENV{PEM2OPENPGP_USAGE_FLAGS},
 577                       }
 578                      );
 579   }
 580   elsif (/^openpgp2ssh$/) {
 581       my $fpr = shift;
 582       my $instream;
 583       open($instream,'-');
 584       binmode($instream, ":bytes");
 585       openpgp2ssh($instream, $fpr);
 586   }
 587   else {
 588     print STDERR "Unrecognized keytrans call.\n";
 589     die 1;
 590   }
 591 }
 592