bertos/cpu/arm/hw/switch_ctx_arm.S

   1 /**
   2  * \file
   3  * <!--
   4  * This file is part of BeRTOS.
   5  *
   6  * Bertos is free software; you can redistribute it and/or modify
   7  * it under the terms of the GNU General Public License as published by
   8  * the Free Software Foundation; either version 2 of the License, or
   9  * (at your option) any later version.
  10  *
  11  * This program is distributed in the hope that it will be useful,
  12  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  13  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14  * GNU General Public License for more details.
  15  *
  16  * You should have received a copy of the GNU General Public License
  17  * along with this program; if not, write to the Free Software
  18  * Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA  02110-1301  USA
  19  *
  20  * As a special exception, you may use this file as part of a free software
  21  * library without restriction.  Specifically, if other files instantiate
  22  * templates or use macros or inline functions from this file, or you compile
  23  * this file and link it with other files to produce an executable, this
  24  * file does not by itself cause the resulting executable to be covered by
  25  * the GNU General Public License.  This exception does not however
  26  * invalidate any other reasons why the executable file might be covered by
  27  * the GNU General Public License.
  28  *
  29  * Copyright 2007, 2008 Develer S.r.l. (http://www.develer.com/)
  30  *
  31  * -->
  32  *
  33  * \brief ARM context switch
  34  *
  35  *
  36  * \author Stefano Fedrigo <aleph@develer.com>
  37  * \author Francesco Sacchi <batt@develer.com>
  38  * \author Andrea Righi <arighi@develer.com>
  39  */
  40
  41 #include "cfg/cfg_proc.h"
  42
  43 /* void asm_switch_context(void **new_sp [r0], void **save_sp [r1]) */
  44 .globl asm_switch_context
  45 asm_switch_context:
  46         /* Save registers */
  47         stmfd   sp!, {r4 - r11, lr}
  48         /* Save old stack pointer */
  49         str     sp, [r1]
  50         /* Load new stack pointer */
  51         ldr     sp, [r0]
  52         /* Load new registers */
  53         ldmfd   sp!, {r4 - r11, pc}
  54
  55 #if CONFIG_KERN_PREEMPT
  56
  57 /* ARM interrupt mode with IRQ and FIQ disabled */
  58 #define ARM_IRQ_MODE 0xD2
  59 /* ARM supervisor mode with IRQ and FIQ disabled */
  60 #define ARM_SVC_MODE 0xD3
  61
  62 .globl asm_irq_switch_context
  63 asm_irq_switch_context:
  64         /* Return if preemption is not needed */
  65         bl      proc_needPreempt
  66         cmp     r0, #0
  67         ldmeqfd sp!, {r0 - r3, ip, pc}^
  68
  69         /* Otherwise restore regs used by the ISR */
  70         ldmfd   sp!, {r0 - r3, ip, lr}
  71
  72         /* Save current process context */
  73         msr     cpsr_c, #ARM_SVC_MODE
  74         stmfd   sp!, {r0 - r3, ip, lr}
  75
  76         /* Save lr_irq and spsr_irq in process stack */
  77         msr     cpsr_c, #ARM_IRQ_MODE
  78         mov     r0, lr
  79         mrs     r1, spsr
  80         msr     cpsr_c, #ARM_SVC_MODE
  81         stmfd   sp!, {r0, r1}
  82
  83         /* Perform the context switch */
  84         bl      proc_preempt
  85
  86         /* Restore lr_irq and spsr_irq from process stack */
  87         ldmfd   sp!, {r0, r1}
  88         msr     cpsr_c, #ARM_IRQ_MODE
  89         mov     lr, r0
  90         msr     spsr_cxsf, r1
  91
  92         /* Restore process regs */
  93         msr     cpsr_c, #ARM_SVC_MODE
  94         ldmfd   sp!, {r0 - r3, ip, lr}
  95
  96         /* Exit from ISR */
  97         msr     cpsr_c, #ARM_IRQ_MODE
  98         movs    pc, lr
  99 #endif /* CONFIG_KERN_PREEMPT */