src/keytrans/pem2openpgp

   1 #!/usr/bin/perl -w -T
   2
   3 # pem2openpgp: take a PEM-encoded RSA private-key on standard input, a
   4 # User ID as the first argument, and generate an OpenPGP certificate
   5 # from it.
   6
   7 # Authors:
   8 #  Jameson Rollins <jrollins@finestructure.net>
   9 #  Daniel Kahn Gillmor <dkg@fifthhorseman.net>
  10
  11 # Started on: 2009-01-07 02:01:19-0500
  12
  13 # License: GPL v3 or later (we may need to adjust this given that this
  14 # connects to OpenSSL via perl)
  15
  16 use strict;
  17 use warnings;
  18 use Crypt::OpenSSL::RSA;
  19 use Crypt::OpenSSL::Bignum;
  20 use Digest::SHA1;
  21 use MIME::Base64;
  22
  23 ## make sure all length() and substr() calls use bytes only:
  24 use bytes;
  25
  26 # make an old-style packet out of the given packet type and body.
  27 # old-style  (see RFC 4880 section 4.2)
  28 sub make_packet {
  29   my $type = shift;
  30   my $body = shift;
  31
  32   my $len = length($body);
  33
  34   my $lenbytes;
  35   my $lencode;
  36
  37   if ($len < 2**8) {
  38     $lenbytes = 0;
  39     $lencode = 'C';
  40   } elsif ($len < 2**16) {
  41     $lenbytes = 1;
  42     $lencode = 'n';
  43   } elsif ($len < 2**31) {
  44     ## not testing against full 32 bits because i don't want to deal
  45     ## with potential overflow.
  46     $lenbytes = 2;
  47     $lencode = 'N';
  48   } else {
  49     ## what the hell do we do here?
  50     $lenbytes = 3;
  51     $lencode = '';
  52   }
  53
  54   return pack('C'.$lencode, 0x80 + ($type * 4) + $lenbytes, $len).
  55     $body;
  56 }
  57
  58
  59 # takes a Crypt::OpenSSL::Bignum, returns it formatted as OpenPGP MPI
  60 # (RFC 4880 section 3.2)
  61 sub mpi_pack {
  62   my $num = shift;
  63
  64   my $val = $num->to_bin();
  65   my $mpilen = length($val)*8;
  66
  67 # this is a kludgy way to get the number of significant bits in the
  68 # first byte:
  69   my $bitsinfirstbyte = length(sprintf("%b", ord($val)));
  70
  71   $mpilen -= (8 - $bitsinfirstbyte);
  72
  73   return pack('n', $mpilen).$val;
  74 }
  75
  76 # FIXME: genericize this to accept either RSA or DSA keys:
  77 sub make_rsa_key_body {
  78   my $key = shift;
  79   my $timestamp = shift;
  80
  81   my ($n, $e) = $key->get_key_parameters();
  82
  83   return
  84     pack('CN', 4, $timestamp).
  85       pack('C', 1). # RSA
  86         mpi_pack($n).
  87           mpi_pack($e);
  88
  89 }
  90
  91 # expects an RSA key (public or private) and a timestamp
  92 sub fingerprint {
  93   my $key = shift;
  94   my $timestamp = shift;
  95
  96   my $rsabody = make_rsa_key_body($key, $timestamp);
  97
  98   return Digest::SHA1::sha1_hex(pack('Cn', 0x99, length($rsabody)).$rsabody);
  99 }
 100
 101 my $holdTerminator = $/;
 102 undef $/;
 103 my $buf = <STDIN>;
 104
 105
 106 my $rsa = Crypt::OpenSSL::RSA->new_private_key($buf);
 107
 108 $rsa->use_sha1_hash();
 109 $rsa->use_no_padding();
 110
 111 if (! $rsa->check_key()) {
 112   die "key does not check";
 113 }
 114
 115 my $uid = 'fake key (do not use) <test@example.org>';
 116
 117
 118
 119 my $version = pack('C', 4);
 120 # strong assertion of identity:
 121 my $sigtype = pack('C', 0x13);
 122 # RSA
 123 my $pubkey_algo = pack('C', 1);
 124 # SHA1
 125 my $hash_algo = pack('C', 2);
 126
 127
 128
 129 my $timestamp = 1231003584;
 130
 131 my $creation_time_packet = pack('CCN', 5, 2, $timestamp);
 132
 133
 134 # usage: signing and certification:
 135 my $flags = 0x03;
 136 my $usage_packet = pack('CCC', 2, 27, $flags);
 137
 138
 139 # expire in 2 days:
 140 my $expires_in = 86400*2;
 141 my $expiration_packet = pack('CCN', 5, 9, $expires_in);
 142
 143
 144 # prefer AES-256, AES-192, AES-128, CAST5, 3DES:
 145 my $pref_sym_algos = pack('CCCCCCC', 6, 11, 9, 8, 7, 3, 2);
 146
 147 # prefer SHA-1, SHA-256, RIPE-MD/160
 148 my $pref_hash_algos = pack('CCCCC', 4, 21, 2, 8, 3);
 149
 150 # prefer ZLIB, BZip2, ZIP
 151 my $pref_zip_algos = pack('CCCCC', 4, 22, 2, 3, 1);
 152
 153 # we support the MDC feature:
 154 my $features = pack('CCC', 2, 30, 1);
 155
 156 # keyserver preference: only owner modify (???):
 157 my $keyserver_pref = pack('CCC', 2, 23, 0x80);
 158
 159 my $subpackets_to_be_hashed =
 160   $creation_time_packet.
 161   $usage_packet.
 162   $expiration_packet.
 163   $pref_sym_algos.
 164   $pref_hash_algos.
 165   $pref_zip_algos.
 166   $features.
 167   $keyserver_pref;
 168
 169 my $subpacket_octets = pack('n', length($subpackets_to_be_hashed));
 170
 171 my $sig_data_to_be_hashed =
 172   $version.
 173   $sigtype.
 174   $pubkey_algo.
 175   $hash_algo.
 176   $subpacket_octets.
 177   $subpackets_to_be_hashed;
 178
 179 my $pubkey = make_rsa_key_body($rsa, $timestamp);
 180
 181 #open(KEYFILE, "</home/wt215/gpg-test/key-data");
 182 my $key_data = make_packet(6, $pubkey);
 183
 184 # take the last 16 characters of the fingerprint as the keyid:
 185 my $keyid = substr(fingerprint($rsa, $timestamp), 40 - 16, 16);
 186
 187 # the v4 signature trailer is:
 188
 189 # version number, literal 0xff, and then a 4-byte count of the
 190 # signature data itself.
 191 my $trailer = pack('CCN', 4, 0xff, length($sig_data_to_be_hashed));
 192
 193 my $uid_data =
 194   pack('CN', 0xb4, length($uid)).
 195   $uid;
 196
 197 my $datatosign =
 198   $key_data.
 199   $uid_data.
 200   $sig_data_to_be_hashed.
 201   $trailer;
 202
 203 my $data_hash = Digest::SHA1::sha1_hex($datatosign);
 204
 205
 206 my $issuer_packet = pack('CCH16', 9, 16, $keyid);
 207
 208 my $sig = Crypt::OpenSSL::Bignum->new_from_bin($rsa->sign($datatosign));
 209
 210 my $sig_body =
 211   $sig_data_to_be_hashed.
 212   pack('n', length($issuer_packet)).
 213   $issuer_packet.
 214   pack('n', hex(substr($data_hash, 0, 4))).
 215   mpi_pack($sig);
 216
 217 print make_packet(6, $pubkey);
 218 print make_packet(13, $uid);
 219 print make_packet(2, $sig_body);
 220
 221 $/ = $holdTerminator;